1 /*
2 * Common module linker script, always used when linking a module.
3 * Archs are free to supply their own linker scripts. ld will
4 * combine them automatically.
5 */
6 #ifdef CONFIG_UNWIND_TABLES
7 #define DISCARD_EH_FRAME
8 #else
9 #define DISCARD_EH_FRAME *(.eh_frame)
10 #endif
11
12 #include <asm-generic/codetag.lds.h>
13
14 SECTIONS {
15 /DISCARD/ : {
16 *(.discard)
17 *(.discard.*)
18 *(.export_symbol)
19 }
20
21 __ksymtab 0 : { *(SORT(___ksymtab+*)) }
22 __ksymtab_gpl 0 : { *(SORT(___ksymtab_gpl+*)) }
23 __kcrctab 0 : { *(SORT(___kcrctab+*)) }
24 __kcrctab_gpl 0 : { *(SORT(___kcrctab_gpl+*)) }
25
26 .ctors 0 : ALIGN(8) { *(SORT(.ctors.*)) *(.ctors) }
27 .init_array 0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
28
29 .altinstructions 0 : ALIGN(8) { KEEP(*(.altinstructions)) }
30 __bug_table 0 : ALIGN(8) { KEEP(*(__bug_table)) }
31 __jump_table 0 : ALIGN(8) { KEEP(*(__jump_table)) }
32
33 __patchable_function_entries : { *(__patchable_function_entries) }
34
35 #ifdef CONFIG_ARCH_USES_CFI_TRAPS
36 __kcfi_traps : { KEEP(*(.kcfi_traps)) }
37 #endif
38
39 #ifdef CONFIG_LTO_CLANG
40 /*
41 * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and
42 * -ffunction-sections, which increases the size of the final module.
43 * Merge the split sections in the final binary.
44 */
45 .bss : {
46 *(.bss .bss.[0-9a-zA-Z_]*)
47 *(.bss..L*)
48 }
49
50 .data : {
51 *(.data .data.[0-9a-zA-Z_]*)
52 *(.data..L*)
53 CODETAG_SECTIONS()
54 }
55
56 .rodata : {
57 *(.rodata .rodata.[0-9a-zA-Z_]*)
58 *(.rodata..L*)
59 }
60 #else
61 .data : {
62 CODETAG_SECTIONS()
63 }
64 #endif
65 }
66
67 /* bring in arch-specific sections */
68 #include <asm/module.lds.h>
Linux® is a registered trademark of Linus Torvalds in the United States and other countries.
TOMOYO® is a registered trademark of NTT DATA CORPORATION.